#include <Arduino.h>
#include <WiFi.h>
#include <Wire.h>
#include <Adafruit_BME280.h>
#include <Ticker.h>
#include <WiFiUdp.h>
#include <time.h>

// Wifi
const char SSID[] = "";
const char PASSWORD[] = "";

// Servidor NTP
const char NTP_SERVER[] = "ntp.nict.jp";

// Graphite
IPAddress graphite(192,168,0,10);

// Ticker
Ticker ticker;
bool flagTicker = false;

// Sensor BME280
Adafruit_BME280 bme;

void setTicker() {
    flagTicker = true;
}

// UDP
WiFiUDP udp;

void setup() {
  Serial.begin(115200);
  while (!Serial);

  if (!bme.begin(0x76)) {
    Serial.println("¡Error en el sensor BME280!");
    while (1);
  }

  // Conexión WiFi
  WiFi.begin(SSID, PASSWORD);
  Serial.print("Conectando a WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(100);
  }

  IPAddress ipaddr, gateway;
  ipaddr = WiFi.localIP();
  gateway = WiFi.gatewayIP();
  Serial.println("WiFi Conectado.");
  Serial.print("IPAddr:");
  Serial.println(ipaddr);
  Serial.print("Gateway:");
  Serial.println(gateway);

  // NTP
  configTime(9 * 3600L, 0, NTP_SERVER); 

  // ms
  struct timeval tv;
  int ms = 0;
  while(1) {
     if (gettimeofday(&tv, NULL) != 0) {
       Serial.println("error gettimeofday.");
     }else{
      ms = tv.tv_usec / 1000LL;
    }
    if(ms == 0) {
        ticker.attach_ms(1000, setTicker);
        Serial.println("ticker configurado");
        break;
    }
  }
}

void send() {
    time_t now;
    time(&now); 
    udp.beginPacket(graphite, 2003);
    udp.println("sec.esp32.temperature " + String(bme.readTemperature()) + " " + now);
    udp.println("sec.esp32.humidity " + String(bme.readHumidity()) + " " + now);
    udp.println("sec.esp32.pressure " + String(bme.readPressure() / 100) + " " + now);
    udp.endPacket();
}

void loop() {
  if(flagTicker) {
      send();
      flagTicker = false;
  }
}